CADxp: Propdess - CADxp

Aller au contenu

Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

Propdess

#1 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 29 janvier 2009 - 14:45

Bonjour à tous

Je voudrais savoir comment je peux récupérer les propriétés personnalisées d'un fichier gabarit afin de les importer sur mon fichier en cour

Cordialement
0

#2 L'utilisateur est hors-ligne   capde06 

  • ceinture noire 1er dan
  • Groupe : Membres
  • Messages : 604
  • Inscrit(e) : 22-juin 05

Posté 29 janvier 2009 - 14:56

moi je fais comme ca, mais il y a peut etre mieux

menu express > tools > system variable editor

la, tu peux expoter importer
0

#3 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 29 janvier 2009 - 16:18

Peux tu m'expliquer plus en détail les étapes car mon niveau d'anglais est faible

Merci
0

#4 L'utilisateur est hors-ligne   t.erie 

  • ceinture verte
  • Groupe : Membres
  • Messages : 70
  • Inscrit(e) : 26-octobre 05

Posté 29 janvier 2009 - 16:38

Bonjour,
Commande PROPULATE des outils express

0

#5 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 30 janvier 2009 - 09:03

Peut tu m'expliquer comment marche cette commande stp
0

#6 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 02 février 2009 - 16:26

Bonjour

Quelqu'un un pourrait il m expliquer la démarche pour que utiliser cette commande ou récupérer les propriétés personnaliser d'un être dessin avec une autre méthode

Cordialement

0

#7 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 8450
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 02 février 2009 - 18:06

Citation

Quelqu'un un pourrait il m expliquer la démarche pour que utiliser cette commande ou récupérer les propriétés personnaliser d'un être dessin avec une autre méthode


D'après moi, il n'y a aucun problème en passant par les CHAMPS.
Image IPB

Bureau d'études dessin.
Spécialiste Escaliers
Développement - Formation

./__\.
(.°=°.)
0

#8 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 05 février 2009 - 17:37

Désolée mais sa m'aide pas à résoudre mon problème
0

#9 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11259
  • Inscrit(e) : 02-septembre 05

Posté 05 février 2009 - 19:22

Salut,

Si j'ai bien compris la demande, voilà un LISP qui permet d'importer les propriétés personnalisées d'un autre dessin (dwg) ou gabarit (dwt).

;; IMPOROP (gile)

;; Importe dans le dessin courant les propriétés personnalisées d'un fichier (dwg ou dwt)


(defun c:improp	(/ target filename doc odbx source)

  (or *acdoc*

      (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))

  )

  (setq target (vla-get-SummaryInfo *acdoc*))

  (if

    (setq filename (getfiled "Choisir le fichier source"

			     (getvar 'dwgprefix)

			     "dwg;dwt"

			     0

		   )

    )

     (progn

       (if

	 (not

	   (and

	     (setq

	       doc (GetItem

		     (vla-get-Documents (vlax-get-acad-object))

		     (strcat (vl-filename-base filename) ".dwg")

		   )

	     )

	     (= filename (vla-get-FullName doc))

	   )

	 )

	  (setq	doc  (OpenDrawingDBX filename)

		odbx T

	  )

       )

       (setq source (vla-get-SummaryInfo doc)

	     n	    -1

       )

       (foreach	p

		'(Author Comments HyperlinkBase KeyWords Subject Title)

	 (if (/= "" (setq prop (vlax-get source p)))

	   (vlax-put target p prop)

	 )

       )

       (repeat (vla-NumCustomInfo source)

	 (vla-GetCustomByIndex source (setq n (1+ n)) 'key 'val)

	 (vla-AddCustomInfo target key val)

       )

       (and odbx (vlax-release-object doc))

     )

  )

  (princ)

)


;;; Accéder à un dessin fermé


(defun OpenDrawingDBX (filename / objdbx release)

  (setq	objdbx

	 (vlax-create-object

	   (if (< (setq release (atoi (getvar "ACADVER"))) 16)

	     "ObjectDBX.AxDbDocument"

	     (strcat "ObjectDBX.AxDbDocument." (itoa release))

	   )

	 )

  )

  (vla-open objdbx filename)

  objdbx

)


;;; GetItem (gile)

;;; Retourne le vla-object de l'item s'il est présent dans la collection

;;;

;;; Arguments

;;; col : la collection (vla-object)

;;; name : le nom de l'objet (string) ou son indice (entier)

;;;

;;; Retour : le vla-object ou nil


(defun GetItem (col name / obj)

  (vl-catch-all-apply

    (function (lambda () (setq obj (vla-item col name))))

  )

  obj

)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#10 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 11 février 2009 - 10:54

Salut Giles

Tu as exactement compris mon souci et je te remercie pour ton aide.J'ai copiée ton lisp dans un fichier texte avec une extantsion lsp.Je charge l'application sur autocad.Je lance la commande "improp"' une fenêtre apparait pour le choix de mon fichier donc je le sélectionne mais il ne me copie pas les propriétés personnalisés du fichier.Donc peux tu m'aider pour savoir d'où vient l'erreur si elle est dans le lisp ou dans ma démarche.

Voici ce que m'indique autocad dans la fenêtre de commande :
Commande: improp
; erreur: type d'argument incorrect: fixnump: nil


Merci d'avance

0

#11 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 11 février 2009 - 11:02

Salut Giles

Désolé pour le message précédent j'ai été trop vite dans ma démarche. Donc le lisp marche bien si le dessin est ouvert par contre dans ton lisp tu m'explique une manipulationsi le dessin est fermé.Le soucis étant que je ne connais rien au lisp à part son utilisation donc pourrait tu stp m'expliquer tout la manipulation à réaliser si le fichier est fermé

Merci
0

#12 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11259
  • Inscrit(e) : 02-septembre 05

Posté 11 février 2009 - 11:28

Salut,

L'accès à un dessin autre que le document actif en LISP diffère suivant que le dessin est ouvert ou fermé.
Brièvement, pour "lire" un dessin fermé, il faut créer un objet DBX qui pointe sur ce fichier. C'est à ça que sert la routine "OpenDrawingDBX".

Pour l'utilisateur, cette opération est invisible. Le LISP cherche dans les documents ouverts et, s'il ne trouve rien, lance OpenDrawingDBX pour lire le fichier fermé.

D'après les test que j'ai fait, ça fonctionne que le fichier source soit ouvert ou fermé.
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#13 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 11 février 2009 - 12:06

Salut

Faut il que je crée un nouveau fichier car de mon côté si le dessin est fermé il marque l'erreur
; erreur: type d'argument incorrect: fixnump: nil


0

#14 L'utilisateur est hors-ligne   lili2006 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11984
  • Inscrit(e) : 21-décembre 05

Posté 11 février 2009 - 12:24

Bonjour à toutes et tous,

Idem chez moi, après ouverture de la BD et choix du fichier =>

Citation

Commande:
Commande: improp
; erreur: type d'argument incorrect: fixnump: nil
Commande:


Quelle genre de propriétés ?

Présentation, calques, blocs, styles de textes, cotes,....

Car même sur un fichier ouvert, il ne se passe rien chez moi ! (V2008 pleine),...
0

#15 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 11 février 2009 - 12:54

Salut Lili

Il s'agit des propriétés personnalisées d'un fichier.

Tu les retrouves en suivant ce chemin Fichier => Propriété du dessin => onglet personnaliser

Elles te permettent de crée des champs personnalisés.

Bye
0

#16 L'utilisateur est hors-ligne   lili2006 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11984
  • Inscrit(e) : 21-décembre 05

Posté 11 février 2009 - 13:10

Re,

Ok !

Merci de ta réponse ayoros,..

Je vais regarder ça de + près!
0

#17 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11259
  • Inscrit(e) : 02-septembre 05

Posté 11 février 2009 - 22:44

Salut,

Il y avait une faute de frappe dans la routine OpenDrawingDBX.
C'est réparé.
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#18 L'utilisateur est hors-ligne   ayoros 

  • ceinture verte
  • Groupe : Membres
  • Messages : 72
  • Inscrit(e) : 25-août 08

Posté 13 février 2009 - 08:39

Super sa marche nickel

Merci pour le temps que tu m'as consacrée.

Bonne journée à tous

Ciao
0

#19 L'utilisateur est hors-ligne   Olivier_CEA_Grenoble 

  • Advanced Member
  • PipPipPip
  • Groupe : Membres
  • Messages : 30
  • Inscrit(e) : 18-mars 09

Posté 01 juin 2015 - 12:23

Bonjour

Merci Gile.
Un problème de lisp, un coup de CadXp, une réponse de Gile. :rolleyes:
Il y a tout IcI, j'avais un problème de récupération de dessin avec données personalisées a faire sous MAP.

Avec Gile c'est plus facile. :D

Je finis mon outil et je le met en ligne
0

Partager ce sujet :


Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

1 utilisateur(s) en train de lire ce sujet
0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)